fimex2d_example.F90

Example on using the high-level 2d fimex-fortran interface

PROGRAM fimex2d_example
  !
  !
  USE fimex, ONLY  : fimexio,set_filetype,filetype_rw
  USE fimex2d,ONLY : epoch2dtg,fi_error,fi_get_dimensions,fi_read_dimension,fi_read_field,&
                     fi_write_field,ikind,rkind
  IMPLICIT NONE
  CHARACTER(LEN=1024)                            :: arg,infile,outfile,fileformat,configfile
  CHARACTER(LEN=1024)                            :: ctemp2m="air_temperature_2m"
  CHARACTER(LEN=1024)                            :: dimname_t
  CHARACTER(LEN=10)                              :: cdtg
  INTEGER                                        :: i,t
  INTEGER(KIND=IKIND)                            :: nx,ny
  LOGICAL                                        :: found12
  TYPE(fimexio)                                  :: fio_in,fio_out
  REAL(KIND=8),DIMENSION(:,:),ALLOCATABLE        :: t2m
  INTEGER,DIMENSION(:),ALLOCATABLE               :: times
  REAL(KIND=8),DIMENSION(:),ALLOCATABLE          :: ztimes
  REAL(KIND=8)                                   :: basetime,ztime
  INTEGER                                        :: ntimes,ierr

  ! Set arguments
  IF ((command_argument_count() /= 3 ) .AND. (command_argument_count() /= 4 ) ) THEN
    WRITE(*,*) "Usage: ./fimex2d_example infile outfile infile-fileformat [configfile]"
    CALL abort
  ENDIF

  configfile=""
  DO i = 1, command_argument_count()
    CALL get_command_argument(i, arg)
    SELECT CASE (i)
      CASE(1)
         infile=arg
      CASE(2)
         outfile=arg
      CASE(3)
         fileformat=arg
         SELECT CASE (fileformat)
            CASE("felt","FELT","FLT","flt")
               fileformat="felt"
            CASE("GRIB","grib","grb","GRB","GRIB2","grib2","grb2","GRB2")
               fileformat="grib"
            CASE("netcdf","NETCDF","nc","NC")
               fileformat="netcdf"
            CASE DEFAULT
              WRITE(*,*) "Invalid file format: "//fileformat
              CALL abort
         END SELECT
      CASE(4)
         IF (command_argument_count() == 4 ) THEN
           configfile=arg
         ENDIF
    END SELECT
  END DO
  IF (( trim(fileformat) == "felt" ) .OR. ( trim(fileformat) == "grib" )) THEN
    IF ( configfile == "" ) THEN
      WRITE(*,*) 'No config file provided, but is mandatory for '//fileformat
      CALL abort
    ENDIF
  ENDIF

  ierr=fio_in%OPEN(trim(infile),configfile,set_filetype(fileformat))
  IF ( ierr /= 0 ) CALL fi_error("Error opening "//trim(infile))
  ierr=fio_out%OPEN(trim(outfile),"",set_filetype("netcdf",filetype_rw))
  IF ( ierr /= 0 ) CALL fi_error("Error opening "//trim(outfile))

  WRITE(*,*) "List variables in input file "//trim(infile)
  DO i = 1,int(fio_in%VARIABLES_SIZE())
    WRITE(*,*) "Found:  ",i, " ", trim(fio_in%GET_VARNAME(i))
  END DO

  ! Get dimensions from temperature variable
  CALL fi_get_dimensions(fio_in,trim(ctemp2m),nx=nx,ny=ny,ntimes=ntimes,dimname_t=dimname_t,basetime=basetime)

  ! Read times in file
  ALLOCATE(times(0:ntimes-1))
  ALLOCATE(ztimes(0:ntimes-1))
  WRITE(*,*) 'Listing times in file:'
  CALL fi_read_dimension(fio_in,ntimes,trim(dimname_t),ztimes,"seconds since 1970-01-01 00:00:00 +00:00")
  DO i=0,ntimes-1
    times(i)=epoch2dtg(ztimes(i))
    WRITE(*,*) i,times(i)
  ENDDO
  DEALLOCATE(ztimes)

  ALLOCATE(t2m(nx,ny))
  ! Loop forecast and set variables
  found12=.false.
  time_loop: DO t=0,ntimes-1

    WRITE(cdtg,'(I10.10)') times(t)
    IF ( cdtg(9:10)  == "12" ) THEN
      IF (.NOT. found12 ) THEN
        CALL fi_read_field(fio_in,trim(ctemp2m),nx,ny,t2m,t,cunit="celsius",time=ztime,verbosity=2)
        IF ( times(t) /= epoch2dtg(ztime)) CALL fi_error("Mismatch in time for T2M")
        found12=.true.
        EXIT time_loop
      ENDIF
    ENDIF
  ENDDO time_loop

  IF (found12) THEN
    CALL fi_write_field(fio_out,trim(ctemp2m),nx,ny,t2m,verbosity=2)
  ELSE
    CALL fi_error("Variable for 12 UTC was not found")
  ENDIF

  ierr=fio_in%CLOSE()
  ierr=fio_out%CLOSE()

  ! Deallocation
  DEALLOCATE(times)
  DEALLOCATE(t2m)

END PROGRAM fimex2d_example